yab | yet another Basic for HAIKU - Snippets

Deskbar tray status indicator.

Mon, 25 Jun 2018 20:02:02 +0300

Add a status indicator to the deskbar tray.

Code:
#!yab

doc Place a description of your

doc program here.

doc

doc Author, date, license

// set DEBUG = 1 to print out all messages on the console

DEBUG = 1

dir$=attribute get$ "",""

dir$=dir$+"/"

OpenWindow()

// Main Message Loop

dim msg$(1)

while(not leavingLoop)

    nCommands = token(message$, msg$(), "|")

    for everyCommand = 1 to nCommands

        if(DEBUG and msg$(everyCommand)<>"") print msg$(everyCommand)

        switch(msg$(everyCommand))

            case "_QuitRequested"

            case "MainWindow:_QuitRequested"

                leavingLoop = true

                break

            case "on/off"

                if off=1 then

                    off=0

                    OPTION SET "on/off", "Label", "Stop"

                    system("copyattr -n BEOS:ICON "+dir$+"Color_12_Green "+dir$+"On-Off")

                    if link=1 then

                    system("desklink --remove=On-Off")

                    system("desklink \"cmd=Remove replicant:desklink --remove=On-Off\" "+dir$+"On-Off")

                    endif

                else

                    OPTION SET "on/off", "Label", "Run"

                    system("copyattr -n BEOS:ICON "+dir$+"Color_06_Red "+dir$+"On-Off")

                    off=1

                    if link=1 then

                    system("desklink --remove=On-Off")

                    system("desklink \"cmd=Remove replicant:desklink --remove=On-Off\" "+dir$+"On-Off")

                    endif

                endif

            break

            case "link"

                if link=0 then

                system("desklink \"cmd=Remove replicant:desklink --remove=On-Off\" "+dir$+"On-Off")

                OPTION SET "link", "Label", "Remove"

                    link=1

                else 

                    system("desklink --remove=On-Off")

                    link=0

                    OPTION SET "link", "Label", "DeskLink"

                endif

            break

            default    

        end switch

    next everyCommand

wend

CloseWindow()

end

// Setup the main window here

sub OpenWindow()

    window open 100,100 to 600,500, "MainWindow", "On-Off"

    off=1

    link=0

    button 30,30 to 80,50, "on/off", "Run", "MainWindow"

    button 30,100 to 120,120, "link", "DeskLink", "MainWindow"  

    return

end sub

// Close down the main window

sub CloseWindow()

    system("copyattr -n BEOS:ICON "+dir$+"Color_06_Red "+dir$+"On-Off")

    system("desklink --remove=On-Off")

    window close "MainWindow"

    return

end sub

on-off.zip (Size: 56.21 KB / Downloads: 4)

finding a process id

Fri, 22 Jun 2018 22:59:34 +0300

Sometimes it is necessary to kioll a running process. This is not easy if the process id has not been saved. The following program finds the process id from the shell. I call the program:

pid

Code:
#!yab

program$=peek$("argument")

program$=trim$(program$)

if program$="" then

    print "usage:  pid  programname"

    exit

endif

a$=system$("ps "+program$)

dim w$(1) 

num=token(a$,w$())

if arraysize(w$(),1)< 7 then

    print program$+" not found"

    exit

endif 

print w$(7)

This can be used in a shell script:

Code:
#!sh

pid Terminal>Terminal.pid

pid=`cat Terminal.pid`

kill $pid

Large font textconterol

Mon, 19 Feb 2018 20:23:46 +0200

A textcontrol cannot set the text font, but a textedit can.

this example shows how to use a one-line textedit as a textcontrol and use a large font.

Code:
#!yab

doc Place a description of your

doc program here.

doc

doc Author, date, license

// set DEBUG = 1 to print out all messages on the console

DEBUG = 0

OpenWindow()

// Main Message Loop

dim msg$(1)

while(not leavingLoop)

    ret = TEXTEDIT GET "test", "countlines"

    if ret>1 then

    a$=textedit get$ "test"

    print a$

    ret = 0

    TEXTEDIT CLEAR "test"

    endif

    nCommands = token(message$, msg$(), "|")

    for everyCommand = 1 to nCommands

        if(DEBUG and msg$(everyCommand)<>"") print msg$(everyCommand)

        switch(msg$(everyCommand))

            case "_QuitRequested"

            case "MainWindow:_QuitRequested"

                leavingLoop = true

                break

            default

        end switch

    next everyCommand

wend

CloseWindow()

end

// Setup the main window here

sub OpenWindow()

    window open 100,100 to 600,500, "MainWindow", "Main Window"

    textedit 10,10 to 300,50, "test", 0,"MainWindow"

    TEXTEDIT SET "test", "font", "DejaVu Sans,Condensed Bold,32"

    return

end sub

// Close down the main window

sub CloseWindow()

    window close "MainWindow"

    return

end sub

Fullscreen programs

Tue, 04 Apr 2017 22:44:35 +0300

This will appear as an appendix in the next version of Programming with yab.

Yab does not have a built-in facility to write apps that run in a formal fullscreen mode. But we can fake it! Writing such a program is not very difficult. It boils down to the following steps:

1, Find out the dimensions of the screen using the PEEK command
2. Create a window from 0, 0 to those dimensions, in other words, cover the entire screen with a window.
3. Remove all the window decor with WINDOW SET
4. Continue writing the rest of the program.

That's all there is to it, really! The following little demo shows how to do this.

Code:
#!yab

doc Fullscreen demo

OpenWindow()

// Main Message Loop

dim msg$(1)

while(not leavingLoop)

//This is a dummy loop just to stop the demo from closing

wend

end

// Setup the main window here

sub OpenWindow()

local xw, yh

xw = peek("desktopwidth")

yh = peek ("desktopheight")

    window open 0,0 to xw,yh, "MainWindow", "Main Window"

    window set "MainWindow", "look", "no-border"

end sub

In an actual program, though, I would do one thing differently. Those values for xw and yh - I am going to need them all over the place once I start placing widgets on this window. So just this once, I would consider making them global rather than local variables. Global variables are not intrinsically evil: if you know what you are doing, a good mixture of global and local variables is perfectly acceptable.

This is of course just a regular application that happens to take up the entire screen. Other apps can hide behind it or come up in front of it. A true full-screen mode is provided by the operating system and prevents that from happening.

There is a way to specify that a yab app should always remain on top (see the documentation for WINDOW SET), but that is normally a bad idea when you are working full-screen. You would prevent your user from getting to Tracker or the Deskbar, for one thing. If you are going to do that, make sure to provide an obvious way to minimize or close your app. Yes, you will need to do it - you can't just leave it to the window tab, because we removed it!

But what if you want your program to toggle between a window and full screen? WINDOW SET can help you there too: it has a range of options for moving and resizing your window.

Getting the system fonts

Mon, 20 Mar 2017 23:03:28 +0200

yab did not include a way to determine the currently set system font. this library file should do the trick!

https://github.com/bbjimmy/yab-lib/tree/...ystemfonts

Code:
//export sub getfont_family$(fonttype$)

//returns the string needed by draw set to set this font -- less the point size.

//export sub getfont_size$(fonttype$)

// returns the piont size of the font

//fonttype$ can be "bold", "book", or "mono"

////////////////////////////////////

sub getsystemfonts()

local a$,num,x

dim font$(1)

a$=system$("message /boot/home/config/settings/system/app_server/fonts")

num=split(a$,font$(),"\n")

for x=2 to 10

    a$=gststring$(font$(x))

    if a$<>"" font$(x)=a$

next

font$(4)=getsize$(font$(4))

font$(7)=getsize$(font$(7))

font$(10)=getsize$(font$(10))

end sub

////////////////////////////////////

sub gststring$(a$)

local x

x=instr(a$,chr$(34))

a$=right$(a$,len(a$)-x)

x=instr(a$,chr$(34))

a$=left$(a$,x-1)

return a$

end sub

////////////////////////////////////

sub getsize$(a$)

x=instr(a$,"(")

a$=right$(a$,len(a$)-x)

x=instr(a$,".")

a$=left$(a$,x-1)

return a$

end sub

////////////////////////////////////

export sub getfont_family$(fonttype$)

dim font$(1)

x=arraysize(font$(),1)

if x=1 getsystemfonts()

fonttype$=lower$(fonttype$) 

if fonttype$="book" return font$(2)+", "+font$(3)+", "

if fonttype$="bold" return font$(5)+", "+font$(6)+", "

if fonttype$="mono" return font$(8)+", "+font$(9)+", "

end sub

////////////////////////////////////

export sub getfont_size$(fonttype$)

dim font$(1)

x=arraysize(font$(),1)

if x=1 getsystemfonts()

fonttype$=lower$(fonttype$) 

if fonttype$="book" return font$(4)

if fonttype$="bold" return font$(7)

if fonttype$="mono" return font$(10)

end sub

using a treebox

Wed, 08 Mar 2017 20:14:16 +0200

Treeboxes are the yab version of the Outline List View. They allow the user to select an item like a listbox while allowing for sub items for each listed item. This takes some special handeling to set-up.

First, add the treebox :

TREEBOX 0,0 to 300,400, "TB", 1, View$

Next add all the top level items in the order to be shown:

TREEBOX ADD "TB", "First Item"
TREEBOX ADD "TB", "Second Item"
TREEBOX ADD "TB", "Third Item"

Now add the sub-items grouped together and in the reverse order:

TREEBOX ADD "TB", "First Item", "Sub item2",0
TREEBOX ADD "TB", "First Item", "Sub item1",0
TREEBOX ADD "TB", "Sub item1", "Detail2", 0
TREEBOX ADD "TB", "Sub item1", "Detail1", 0
TREEBOX ADD "TB", "Second Item", "Sub item2,2",0
TREEBOX ADD "TB", "Second Item", "Sub item2,1",0

Haiku has issues with the outlinelistview therefore yab has the same issue. If one colapsed a menu and later expands the menu and attempts to make a selection, the wrong item is selected. The following is a work-around that will always make the proper selection, although it adds a minor visual glitch.

In the program loop do the following:

if left$(msg$(everyCommand),11)="TB:_Select:" then
tmp=treebox get "TB"
TREEBOX SELECT "TB", tmp
// now process the selection
endif

It seems that treebox get was not included in the documentation. It makes one wonder how many other yab commands are missing from the docs.

The magic here is:

TREEBOX SELECT "TB", tmp

this selects the item, but the loop will come around soon enough to re-select the sub-idem that was really intended. otherwise outlinelistview will continue to reurn the wrong message and the user will see his selection not take effect.

Example program:

Code:
#!yab

doc Place a description of your

doc program here.

doc

doc Author, date, license

// set DEBUG = 1 to print out all messages on the console

DEBUG = 1

dim tbitem$(10)

OpenWindow()

for x=1 to treebox count "TB"

tbitem$(x) = "This should be \""+(treebox get$ "TB",x)+".\"": print tbitem$(x)

next

// Main Message Loop

dim msg$(1)

while(not leavingLoop)

    nCommands = token(message$, msg$(), "|")

    for everyCommand = 1 to nCommands

        if(DEBUG and msg$(everyCommand)<>"") print msg$(everyCommand)

        switch(msg$(everyCommand))

            case "_QuitRequested"

            case "MainWindow:_QuitRequested"

                leavingLoop = true

                break

            default 

        end switch

        if left$(msg$(everyCommand),11)="TB:_Select:" then

            tmp=treebox get "TB"

            TREEBOX SELECT "TB", tmp

            TEXTEDIT CLEAR "TE"

            TEXTEDIT ADD "TE", "Message: "+ msg$(everyCommand) +"\n\n"+tbitem$(tmp)

            endif

    next everyCommand

wend

CloseWindow()

end

// Setup the main window here

sub OpenWindow()

    window open 100,100 to 600,500, "MainWindow", "Main Window"

    Window set "MainWindow","flags", "Not-Zoomable Not-Resizable"

    SPLITVIEW 0,0 TO 500,400, "SplitView", 1, 1, "MainWindow"

    SPLITVIEW SET "SplitView", "Divider", 100

    SPLITVIEW SET "SplitView", "MinimumSizes", 100, 200

    TEXTEDIT 0,0 TO 500,400, "TE", 0,"SplitView2"

    TREEBOX 0,0 to 300,400, "TB", 1, "SplitView1"

    TREEBOX ADD "TB", "First Item"

    TREEBOX ADD "TB", "Second Item"

    TREEBOX ADD "TB", "Third Item"

    TREEBOX ADD "TB", "First Item", "Sub item2",0

    TREEBOX ADD "TB", "First Item", "Sub item1",0

    TREEBOX ADD "TB", "Sub item1", "Detail2", 0

    TREEBOX ADD "TB", "Sub item1", "Detail1", 0

    TREEBOX ADD "TB", "Second Item", "Sub item2,2",0

    TREEBOX ADD "TB", "Second Item", "Sub item2,1",0

end sub    

//close down the main window

sub CloseWindow()

    window close "MainWindow"

    return

end sub

More spinner stuff.

Mon, 16 May 2016 21:29:18 +0300

I added a slinner to a Filebox.

FileboxDemo.yab ( minor changes)

Code:
#!yab

import spinner

import Filebox_spin

dir$ = "/boot/home/"

window open 100,100 to 500,500, "Demo",dir$

Window set "Demo","flags","Not-Zoomable Not-Resizable"

Filebox(10,20,350,385,"Filebox", 1, "Demo")

button 10,0,32,20, "DirUp", "..", "Demo"

FileboxDirectory("Filebox", dir$, true)

dim msg$(1)

inloop = true

while(inloop)

        n = split(message$, msg$(), "|")

    for i=1 to n

        print msg$(i)

        // Quit

        if(msg$(i) = "Demo:_QuitRequested") inloop = false

        // Button pressed and we are not in the root directory

        if(msg$(i) = "DirUp" and dir$"/") then

            t = len(dir$)-1

            while(mid$(dir$,t,1)"/") 

                t = t - 1

            wend

            dir$ = left$(dir$,t)

            WINDOW SET "Demo", "Title", dir$

            FileboxDirectory("Filebox", dir$, false)

        endif

        // An item is invoked

        if(instr(msg$(i),"Filebox:_Invoke:")) then

            position = val(right$(msg$(i),len(msg$(i))-16))

            // if the item is a directory, then update the filebox else print the filename

            if(FileboxIsDirectory("Filebox", position,dir$)) then

                dir$ = dir$ + FileboxName$("Filebox", position) + "/"

                WINDOW SET "Demo", "Title", dir$

                FileboxDirectory("Filebox", dir$, true)

            else

                print dir$+FileboxName$("Filebox", position)

            endif

        endif

    next i

        sleep 0.01

wend

window close "Demo"

Filebox_spin.yab (modified Filebox.yab library file)

Code:
// Filebox is a library to have an easy access to a list of files.

// This is easier than poking around with columnboxes yourself.

// Open a new filebox from (x1,y1) to (x2,y2)

// with the id ID$, the type of scrollbar ScrollbarType on View$

export sub Filebox(x1,y1,x2,y2, ID$, ScrollbarType, View$)

    local myscrollbar

    columnbox x1,y1 to x2,y2, ID$, ScrollbarType, "resizable", View$

    columnbox column ID$, " ", 1, 20, 20, 20, "align-center"

    if(scrollbarType=1 or scrollbarType=3) myscrollbar = peek("scrollbarwidth")

    columnbox column ID$, "Name", 2, 1000, 21, x2-x1-24-myscrollbar, "align-left"

    columnbox color ID$, "Selection-Active", 220,220,250

        columnbox color ID$, "Row-Divider", 255,255,255

        new_spinner(x2-12,y2-12,12,12, ID$, View$)

        spinner_set(1,ID$)

    return

end sub

// Easy interface to a Filebox, simply name a directory

export sub FileboxDirectorySimple(ID$, dir$)

    FileboxDirectory(ID$,dir$,false)

    return

end sub

// return the name of the row position

export sub FileboxName$(ID$, position)

    return columnbox get$ ID$, 2, position

end sub

// return true, if the row position is a directory

export sub FileboxIsDirectory(ID$, position,dir$)

    local t$

    t$ = columnbox get$ ID$, 2, position

    print "t$ "+t$

    //if(t$ =  "__Path__="+path$+Name$"__Mime__=application/x-vnd.Be-directory") return true

    if(system("test -d \""+ dir$+t$+"\"") = 0) system("addattr -t mime BEOS:TYPE application/x-vnd.Be-directory \""+dir$+t$+"\"") : return true

    return false

end sub

// Give a directory and the following options:

// showDot: set this to true to show hidden (dot) files

export sub FileboxDirectory(ID$, dir$, showDot)

display_spinner(ID$)

spin(ID$)

    local t$

    local i

    local n

    local arraysizeDir

    local arraysizeFiles

    dim directories$(1)

    dim files$(1)

    arraysizeDir = 0

    arraysizeFiles = 0

    columnbox clear ID$

    if(showDot) then

        t$ = system$("ls --format=single-column --color=none -aF \""+dir$+"\" |sort -f")

    else

        t$ = system$("ls --format=single-column --color=none -F \""+dir$+"\" |sort -f")

    endif

    dim splitdir$(1)

    spin=1

    n = split(t$, splitdir$(), "\n")

    for i=1 to n-1

    if n=spin spin(ID$):spin=spin+10

                //print dir$+splitdir$(i)

                //print dir$+splitdir$(i)

                if  (right$(splitdir$(i),1)="/") then

               //if(system("test -d \""+ dir$+splitdir$(i)+"\"") = 0) then

                        // comment the if clause out if you want to have the direcotries "." and ".." listed

                        if(splitdir$(i)<>"./" and splitdir$(i)<>"../") then

                            arraysizeDir = arraysizeDir + 1

                            dim directories$(arraysizeDir)

                            splitdir$(i) = left$(splitdir$(i),len( splitdir$(i))-1)

                            directories$(arraysizeDir-1) = splitdir$(i)

                       endif

                // handle files

                else

                        arraysizeFiles = arraysizeFiles + 1

                        dim files$(arraysizeFiles)

                        if right$(splitdir$(i),1)="*" then

                            files$(arraysizeFiles-1) = left$(splitdir$(i), len(splitdir$(i)) -1)

                        elseif right$(splitdir$(i),1)="@" then

                            files$(arraysizeFiles-1) = left$(splitdir$(i), len(splitdir$(i)) -1)

                        else    

                            files$(arraysizeFiles-1) = splitdir$(i)

                        endif

                endif 

    next i

    for i=0 to arraysizeDir-1

        FileboxAdd(ID$, directories$(i), true,dir$)

        spin(ID$)

    next i

    for i=0 to arraysizeFiles-1

        FileboxAdd(ID$, files$(i), false,dir$)

        spin(ID$)

    next i

    hide_spinner(ID$)

    return

end sub

sub FileboxAdd(ID$, Name$, IsFolder, path$)

    local maxpos

    maxpos = (columnbox count ID$) + 1

    a$=""

    if(IsFolder) then

        columnbox add ID$, 1, maxpos, 18, "__SmIC__="+path$+Name$

    else

        columnbox add ID$, 1, maxpos, 18, "__SmIC__="+path$+Name$

    //else    

        //columnbox add ID$, 1, maxpos, 18, "__Mime__=application/octet-stream"

    endif

    columnbox add ID$, 2, maxpos, 20, Name$

    columnbox select ID$, 1

    columnbox select ID$, 0

    return

end sub

Note the spinner in the lower right. It only shows as the file listing is being filled.

A barberpole spinner

Thu, 05 May 2016 19:58:36 +0300

There are times when a process will take a liong time, but a status bar is not usable for feedback as there is no feedback from the process. A barberpole slinner will give the user some idea that the process is still running.
The following is a library and example program

example program

Code:
#!yab

import spinner

// set DEBUG = 1 to print out all messages on the console

DEBUG = 0

OpenWindow()

// Main Message Loop

dim msg$(1)

while(not leavingLoop)

    nCommands = token(message$, msg$(), "|")

    for everyCommand = 1 to nCommands

        if(DEBUG and msg$(everyCommand)<>"") print msg$(everyCommand)

        switch(msg$(everyCommand))

            case "_QuitRequested"

            case "MainWindow:_QuitRequested"

                leavingLoop = true

                break

            case "start"

                display_spinner("horizontal")

                display_spinner("virtictal")

                countdown=1

                break

            case "stop"

                hide_spinner("horizontal")

                hide_spinner("virtictal")

                countdown = 0

                break

            default

        end switch

    next everyCommand

    if countdown >0 then

        countdown=countdown+1

        if countdown=400 countdown=0

    endif    

    if countdown then

        spin("horizontal")

        spin("virtictal")

    endif

wend

CloseWindow()

end

sub OpenWindow()

    window open 100,100 to 600,500, "MainWindow", "Main Window"

    button 80,30 to 150,60, "start", "start", "MainWindow"

    button 180,30 to 250,60, "stop", "stop", "MainWindow"

    new_spinner(100,100,100,0,"horizontal", "MainWindow")

    new_spinner(10,10,50,1,"virtictal", "MainWindow")

    return

end sub

// Close down the main window

sub CloseWindow()

    window close "MainWindow"

    return

end sub

new_spinner( x,y,length,virtical,name$)

x and y are the top left co-ordinates of the spinner.

length is the number of pixels right or down from the x,y origin

if virtical is true, the spinner is virtical otherwise it is horizontal

name$ is the name of the new slinner.

display_spinner(name$) and hide_spinner(name$) show/hide the spinner.

spin(name$) rotates the barber poel one step. This should be in your main program loop. one cannot spin a hidden spinner ( the view for the spinner is removed on hide, and added on show)

the library ( save as spinner.yab and place in the library search path)

Code:
export sub new_spinner(hz,vt,htln,orentationn, name$, view$)

static mumber

number = number+1

dim spinner(number,4)

dim spinnername$(number,2)

spinner(number,1)=hz

spinner(number,2)=vt

spinner(number,3)=htln

if spinner(number,3)=0 spinner(number,3)=1

spinner(number,4)=orentationn

spinnername$(number,1)=name$

spinnername$(number,2)=view$

end sub

export sub display_spinner(name$)

local x,i.number,view$, length

x=arraysize(spinnername$(),1)

for i=1 to x

if (spinnername$(i,1)=name$) number = i

next

view$=spinnername$(number,2)

length=spinner(number,3)

if spinner(number,4) = 0 then

    view spinner(number,1),spinner(number,2) to spinner(number,2)+length,spinner(number,1)+15, name$+"_view", view$

    draw set 0,"HighSolidFill"

    draw set "highcolor",180,180,180, name$+"_view"

    draw rect 0,0 to length,15, name$+"_view"

    draw set "highcolor",225,225,235, name$+"_view"

    draw line 0,15 to length,15, name$+"_view"

    draw line length,0 to length,15 , name$+"_view"

    draw set "highcolor",150,150,150, name$+"_view"    

    draw line 0,0 to 0,15 , name$+"_view"

    draw line 1,0 to length-1,0 , name$+"_view"

    CANVAS 2,2 to length-2,13,  name$, name$+"_view"

    draw set "highcolor", 0,80,225, name$

    draw set "lowcolor", 245,245,245, name$

else

    view spinner(number,1),spinner(number,2) to spinner(number,2)+15,spinner(number,1)+length, name$+"_view", view$

    draw set 0,"HighSolidFill"

    draw set "highcolor",180,180,180, name$+"_view"

    draw rect 0,0 to 15,length, name$+"_view"    

    draw set "highcolor",225,225,235, name$+"_view"

    draw line 0,length to 15,length, name$+"_view"

    draw line 15,0 to 15,length, name$+"_view"

    draw set "highcolor",150,150,150, name$+"_view"

    draw line 0,0 to 14,0 , name$+"_view"

    draw line 0,0 to 0,length , name$+"_view"

    CANVAS 2,2 to 13, length-2, name$, name$+"_view"

    draw set "highcolor", 0,80,225, name$

    draw set "lowcolor", 245,245,245, name$

endif

end sub

export sub hide_spinner(name$)

view remove name$+"_view"

end sub

export sub spin(name$)

local i,length,x

x=arraysize(spinnername$(),1)

for i=1 to x

if (spinnername$(i,1)=name$) number = i

next

length=spinner(number,3)

p = spinner(number,0)

switch p

    case 0    

        pattern$= "030060120240225195135015"

    break

    case 1

        pattern$ = "060120240225195135015030"

    break

    case 2

        pattern$ = "120240225195135015030060"

    break

    case 3

        pattern$ = "240225195135015030060120"

    break

    case 4

        pattern$ = "225195135015030060120240"

    break

    case 5

        pattern$ = "195135015030060120240225"

    break

    case 6

        pattern$ = "135015030060120240225195"

    break

    case 7

        pattern$ = "015030060120240225195135"

    break

end switch

draw set 0, pattern$        

if spinner(number,4) = 0 then // spin to the right or up

     draw rect 0,0 to length-4, 13, name$

     p=p-1

    if p<0 p=7

     spinner(number,0)=p    

else

    draw rect 0,0 to 13 ,length, name$

    p=p+1

    if p=8 p=0

    spinner(number,0)=p    

endif    

end sub

adding the application signature

Sat, 30 Apr 2016 02:29:57 +0300

yab-IDE 2.2.6 adds some convenience to building your application. No-longer is "application/x-vnd.yab-app" the default application signature.

if the yab filename is "MyApp.yab" then the application signature will default to "application/x-vnd.MyApp"

This default can be over-ridden by placing a comment at the beginning of your yab file.

Code:
#!yab

# MIMETYPE "application/x-vnd.MyCoolApp"

This will change the default for your program to "application/x-vnd.MyCoolApp" regardless of the filename. The comment must be the first or second line of your file.

How to cut and paste snippets from this forum

Sun, 10 Apr 2016 22:25:58 +0300

You read the code examples here and you think "that's great let me try it". So you cut the code to the clipboard, paste it into TryThis.yab, and ...

Code:
---Error in TryThis.yab, line 29: syntax error at "0xff"

OK, if you haven't given up on yab yet, here's the issue: some browsers don't send out very "clean" unicode/ascii to the clipboard, and WebPositive is one of them. "0xff" is geek-talk for the number 255 and Extended ASCII 255 should be the letter "ÿ" but in this case it is embedded as an invisible little bit of binary that messes up our code.

The solution is very simple: USE A DIFFERENT BROWSER. Cutting the same code from Qupzilla provides clean text with no hidden surprises.

select mode and radio mode popup menus

Sun, 10 Apr 2016 18:36:37 +0300

I have made a library file for better handeling of popup menus for my yoshi project. This library will allow one to make a popup menu that marks multiple selections or only one to use the popup as a radio selectuion.

test program:

Code:
import popup

window open 100,100 to 310,250, "test", "test"

popup=new_popup("test_name", "test", 1)//radio selection

add_popup_selection$(popup,1,"First selection")

add_popup_selection$(popup,2,"Second selection")

add_popup_selection$(popup,3,"Some other Selection")

add_popup_selection$(popup,4,"Third selection")

add_popup_selection$(popup,5,"Fourth selection")

a$=popup_select$(popup,"Fourth selection")

button 10,20 to 200,40, "popupbutton", "Fourth selection  ▾", "test"

popup1=new_popup("test_name1", "test", 3)//selection mode

add_popup_selection$(popup1,1,"First selection")

add_popup_selection$(popup1,2,"Second selection")

add_popup_selection$(popup1,3,"Some other Selection")

add_popup_selection$(popup1,4,"Third selection")

add_popup_selection$(popup1,5,"Fourth selection")

a$=popup_select$(popup1,"Fourth selection")

button 10,60 to 200,80, "newbutton", "Please make selections ▾", "test"

inloop = true

while(inloop)

    msg$=message$

    if msg$<>"" print msg$

    if instr(msg$,"Quit") inloop=false

    if instr(msg$,"popupbutton") showpopup()

    if instr(msg$,"newbutton") shownewpopup()

wend    

print getselected$(popup)

end

sub showpopup()

selection$=popupdisplay$(10,20,popup)

if selection$<>"" then

    selection$=trim$(selection$)

    a$=popup_select$(popup,selection$)

    if a$="ok" OPTION SET "popupbutton", "Label", selection$+" ▾"

endif

end sub

sub shownewpopup()

selection$=popupdisplay$(10,20,popup1)

if selection$<>"" then

    selection$=trim$(selection$)

    if left$(selection$,3)="√" then // remove the mark to see the real selection

    selection$ = right$(selection$,len(selection$)-4)

    endif

    a$=popup_select$(popup1,selection$)

endif

end sub

The library file:

Code:
////////////////////////////////////////////////////////

export sub new_popup(name$, view$, radio)

static size

size=size+1

dim popup$(size,12,1) // name, view, selections ( up to 10)

dim  popup(size,2) //radio flag, 1=radio, 0=not radio

popup$(size,1,0)=name$

popup$(size,2,0)=view$

popup(size,1)=radio

return size

end sub

////////////////////////////////////////////////////////

export sub add_popup_selection$(popup,number,selection$)

popup$(popup,number+2,0)=selection$

return "ok"

end sub

////////////////////////////////////////////////////////

export sub popup_select$(x,selection$)

local i

for i=3 to 12

    if popup$(x,i,0)=selection$ then

        if  popup(x,1)=1 then

            popup(x,2)=i

            return "ok"

        else

            if popup$(x,i,1)="√ " then

                popup$(x,i,1)=""

            else

                popup$(x,i,1)="√ "

            endif 

            return "ok"

        endif    

    endif

next

return "error"

end sub

////////////////////////////////////////////////////////

export sub popupdisplay$(x,y,popup)

local i, MenuItems$

MenuItems$=""

if popup(popup,1)=1 then

    for i=3 to 10

        if popup$(popup,i,0)<>"" then

            if popup(popup,2)=i  then

                MenuItems$=MenuItems$+"√ "+popup$(popup,i,0)+"|"

            else

                MenuItems$=MenuItems$+"  "+popup$(popup,i,0)+"|"

            endif

        endif

    next

endif    

if popup(popup,1)=0 then

    for i=3 to 10

        if popup$(popup,i,0)<>"" then

            MenuItems$=MenuItems$+popup$(popup,i,0)+"|"

        endif

    next

endif    

if popup(popup,1)=3 then

    for i=3 to 10

        if popup$(popup,i,0)<>"" then

            MenuItems$=MenuItems$+popup$(popup,i,1)+popup$(popup,i,0)+"|"

        endif

    next

endif

MenuItems$=left$(MenuItems$,len(MenuItems$)-1)

Selected$ = POPUPMENU x,y, MenuItems$, popup$(popup,2,0)

return Selected$

end sub

////////////////////////////////////////////////////////

export sub getselected$(x)

return popup$(x,popup(x,2),0)

end sub

name the library file popup.yab and place it in ~/config/settings/yab to use the code.

Tip: Newline stripper

Fri, 18 Mar 2016 11:53:58 +0200

The system$ command is a useful one: it lets you use any Haiku command that you can issue in terminal and returns the output into a string variable. Haiku is quite robust about these variables: once I accidentally requested a megabyte of data to be fed into a$ and yab didn't even blink.

But have you noticed that when you issue a command in terminal, it gives you the result and then opens up a new prompt for you? That is because almost every bash command is terminated by a newline character. This is an invisible code that tells the system "I am finished, you can start a new command prompt now"

So if you issue the command

Code:
tempdir$ = system$("finddir B_COMMON_TEMP_DIRECTORY")

You may think that the result is
/boot/system/cache/tmp

But it is not. It is

/boot/system/cache/tmp

Sometimes this will not matter. But sometimes it does. Suppose you now want to specify your temporary file. you use basic string concatenation, like this

Code:
tempfile$ = tempdir$ + "/my_temp_file"

the result you want is

/boot/system/cache/tmp/my_temp_file

but what you get is

/boot/system/cache/tmp
/my_temp_file

How is your program supposed to make sense of that?

Luckily, getting rid of that pesky newline is very easy. There are probably other ways, but I use this:

Code:
tempdir$ = system$("finddir B_COMMON_TEMP_DIRECTORY") 

tempdir$ = left$(tempdir$, len(tempdir$)-1) //strip off trailing newline

We take the result of the system$ command, then take the part to the left of the newline character and feed it back into the variable.

You could combine these lines into one long command, but code readability would be bad.

But wait! What if the system$ command you are using is one of those rare ones that do not end their result with a newline? No problem.

Code:
tempdir$ = system$("finddir B_COMMON_TEMP_DIRECTORY") 

if instr(tempdir$, "\n", len(tempdir$)) <> 0 then

    tempdir$ = left$(tempdir$, len(tempdir$)-1) //strip off trailing newline

endif

example program - FuzzyTime

Tue, 29 Dec 2015 21:42:15 +0200

This little desktop applet will appear on my repo soon with source included. I post it here just to give people an example of yab in action. It uses a 3rd-party python script called fuzzy_time.py, which you can get from SourceForge, and wraps a minimalist GUI around it.

It took me about two to three hours to write, and I'm sure that shows in the quality of the code There are too manyglobal variables, the capitalization of variables is inconsistent ... works, though.

Code:
#!/bin/env yab

################################

############# Prologue #############

################################

//Yabadabbadoo notification

########DO NOT RENAME THIS FILE!########

//Yabadabbadoo needs it to function.

//ProgramName$ = "FuzzyTime"

//AuthorName$ = "Michel Clasquin-Johnson "

//ProgramVersion$ = "V0.1"

//ProgramBriefDescription$ = "Displays the date and time in \"fuzzy\" format."

//ProgramLicense$ = "Public Domain"

//ProgramAcknowledgements$ ="With thanks to Chris Tsai for fuzzy_time.py"

//*************************

//*****Global Variables****

//*************************

## Technically, yab does not require you to declare global variables,

##It just is a really, really good idea to do it anyway.

// set DEBUG = 1 to print out all messages on the console

DEBUG = 0

//change this to DEBUG = 0 when you are ready to bind the program for distribution

//see if a settings file exist. If so, read positions

open #1,"/boot/home/config/settings/FuzzyTime.settings", "a": close #1 //create the file if it does not exist

open "/boot/home/config/settings/FuzzyTime.settings" for reading as #1

line input #1 across

line input #1 updown

close #1

if across = 0 or updown = 0 then //ie if the settings file was empty

    across = 100

    updown = 100

endif

xwidth = 150

yheight = 75

acrossend = across + xwidth

updownend = updown + yheight

moving=0

DefaultInterval=60

##########################

######Preliminary Commands#####

##########################

## Commands to run before the Main Loop come here.

## e.g. setting up a window with a menu.

IntervalStart=GetTiming() 

OpenWindow()

#######End of Prologue#######

//Yabadabbadoo notification

########DO NOT RENAME THIS FILE!########

//Yabadabbadoo needs it to function.

//Main Message Loop

dim msg$(1)

while(not leavingLoop)

    nCommands = token(message$, msg$(), "|")

    for everyCommand = 1 to nCommands

        if(DEBUG and msg$(everyCommand)<>"") print msg$(everyCommand)

        switch(msg$(everyCommand))

            case "_QuitRequested":

            case "MainWindow:_QuitRequested":

                Ask2Leave()

                break

            case "MainWindow:Help:About":

                Alert ProgramName$ + " " + ProgramVersion$ + "\n" + "by " + AuthorName$ +"\n\n" + ProgramBriefDescription$ + "\n" + ProgramLicense$ + "\n" + ProgramAcknowledgements$, "OK", "none"

            default:

                break

        end switch

    next everyCommand

    CheckMouse()

    if GetTiming() - IntervalStart >DefaultInterval then

        PrintTime()

        IntervalStart = GetTiming()

    endif

wend

sub Ask2Leave()

    local getout

    getout= Alert "Do you want to Quit FuzzyTime?","Quit","Cancel","","Warning"

    switch getout

        case 1

            across=Window Get "MainWindow", "Position-X"

            updown=Window Get "MainWindow", "Position-Y"

            open "/boot/home/config/settings/FuzzyTime.settings" for writing as #1

            print #1 across

            print #1 updown

            close #1

            CloseWindow()

            end

            break

        default

            break

    end switch

end sub

sub CheckMouse()

local mouse$, num, w$(5)

    mouse$ = MOUSE MESSAGE$ ("MainWindow")

    num=token(mouse$, w$(), ":")

    if w$(5)<>"0" Ask2Leave()

    if w$(3)<>"0" MoveWindow()

    wait 0.1 // avoid flickering

end sub

sub CloseWindow()

    //Close down the main window

    window close "MainWindow"

end sub

sub GetTiming()

    local num, w$(4)

    num=token(time$,w$(),"-")

    return val(w$(4))

end sub

sub MoveWindow()

    if moving= 0 then

        window set "MainWindow", "look", "bordered"

        moving = 1

        return

    endif

    if moving = 1 then

        window set "MainWindow", "look", "floating"

        moving = 0

        return

    endif 

end sub

sub OpenWindow()

window open across,updown to acrossend, updownend, "MainWindow", "FuzzyTime"

    window set "MainWindow", "look", "bordered"

    window set "MainWindow", "Flags", "Accept-First-Click"

    window set "MainWindow", "Flags", "not-resizable"

    window set "MainWindow", "Flags", "not-zoomable"

    Window set "MainWindow", "Workspace", "All"

    redc=255: greenc=250: bluec=170

    for f = yheight/2 to 0 step -1

        draw set "highcolor", redc, greenc, bluec, "MainWindow"

        draw line 0, f to xwidth,f, "MainWindow"

        greenc=greenc-1: bluec = bluec -4

    next f

    redc=255: greenc=250: bluec=170

    for f = yheight/2 to yheight

        draw set "highcolor", redc, greenc, bluec, "MainWindow"

        draw line 0, f to xwidth,f, "MainWindow"

        greenc=greenc-1: bluec = bluec -4

    next f

    draw set "highcolor", 0,0,0, "MainWindow"

    Tooltip "MainWindow", "Left-click to move,\nor right-click to Quit."

    textedit 5, 5 to xwidth -5, yheight -5, "TimeBox", 0, "MainWindow" 

    textedit set "TimeBox", "wordwrap", true

    textedit set "TimeBox", "editable", false

    textedit color "TimeBox", "bgcolor", 255,250,170

    Tooltip "TimeBox", "Left-click BORDER to move,\nor right-click BORDER to Quit."

    PrintTime()

end sub

sub PrintTime()

    local the_time$

    the_time$ = system$("fuzzy_time.py") 

    the_time$ = left$(the_time$,len(the_time$)-1) //strip off trailing newline

    textedit clear "TimeBox"

    textedit add "TimeBox", the_time$

end sub

########################################

###DATA statements, if any, come here###

########################################

Ouch! that case statement "case "MainWindow:Help:About":" should not be in there.

Example program - TinyTim

Mon, 24 Aug 2015 19:01:07 +0300

It turns out that you can access tinyurl.com with a single line of bash script. So of course I had to write a 150-line front-end for it.

Code:
#!yab

############# Prologue #############

##Fill in these fields with your own particulars.

##The variables will be used in the About Box

ProgramName$ = "TinyTim"

AuthorName$ = "Michel Clasquin-Johnson "

ProgramVersion$ = "V0.1"

ProgramBriefDescription$ = "TinyTim allows you to send a long URL to tinyurl.com and copy the resulting short URL to the clipboard."

ProgramLicense$ = "Public Domain"

//*****Global Variables****

## Technically, yab does not require you to declare global variables,

##It just is a really, really good idea to do it anyway.

// set DEBUG = 1 to print out all messages on the console

DEBUG = 0

//change this to DEBUG = 0 when you are ready to bind the program for distribution

LongURL$=""

ShortURL$="Shortened URL will appear here after conversion"

######Preliminary Commands#####

## Commands to run before the Main Loop come here.

## e.g. setting up a window with a menu.

OpenWindow()

#######End of Prologue#######

//Main Message Loop

dim msg$(1)

while(not leavingLoop)

    nCommands = token(message$, msg$(), "|")

    for everyCommand = 1 to nCommands

        if(DEBUG and msg$(everyCommand)<>"") print msg$(everyCommand)

        switch(msg$(everyCommand))

            case "_QuitRequested":

            case "MainWindow:_QuitRequested":

                leavingLoop = true

                break

            case "aboutButton"

                Alert ProgramName$ + " " + ProgramVersion$ + "\n" + "by " + AuthorName$ +"\n\n" + ProgramBriefDescription$ + "\n\n" + ProgramLicense$, "OK", "none"

                break

            case "tinyurlButton":

                Launchsurl$()

                break

            case "copyButton":

                Copy2Clipboard()

                break

            default:

                break

        end switch

    next everyCommand

wend

CloseWindow()

end

sub CheckLongURL()

    if  LongURL$ = "" then

        Alert "Please enter a long URL first", "OK", "warning"

        return 0

    end if

    If (left$(LongURL$, 4)<>"www.") and (left$(LongURL$, 5) <> "http:") then

        alert "Is this a valid URL? Please start your URL with www or http. URLs are case sensitive and with no tabs, spaces or trailing lines, please", "OK", "warning"

        return 0

    endif

    if instr(LongURL$, "\n") <> 0 then

    alert "There is an open line or more than one line in your long URL (possibly at the end, did you press ENTER?) Please remove it.", "OK", "warning"

        return 0

    endif

    return 1

end sub

sub CloseWindow()

    //Close down the main window

    window close "MainWindow"

end sub

sub Copy2Clipboard()

    if ShortURL$ = "" return

    clipboard copy ShortURL$

end sub

sub DisplayShortURL()

    draw flush "ShortURLView"

    Draw text 0,20, ShortURL$, "ShortURLView"

end sub

sub ExamineClipboard()

    //this should only happen at program launch

    //if you wish to add an "insert from clipboard" function later

    //it will require a TEXTEDIT CLEAR. But rightclick works so why bother?

    local clipcontent$

    clipcontent$ = clipboard paste$

    if (left$(clipcontent$, 4) = "www.") or (left$(clipcontent$, 5) = "http:") then

        textedit add "URLField", clipcontent$

        LongURL$ = clipcontent$ // not strictly necessary, but better to play safe    

    endif

end sub

sub Launchsurl$()

    local dothis$

    LongURL$ = textedit get$ "URLField"

    if CheckLongURL()= 0 return

    UIOnOff(0)

    dothis$ = "curl 'http://tinyurl.com/api-create.php?url=" + LongURL$ +"'"

    //print dothis$

    ShortURL$ = system$(dothis$)

    DisplayShortURL()

    UIOnOff(1)

end sub

sub OpenWindow()

    //Setup the main window here

    window open 100,100 to 500,280, "MainWindow", ProgramName$

    window set "MainWindow", "look", "floating"

    window set "MainWindow", "feel", "modal-app"

    window set "MainWindow", "flags","not-zoomable"

    window set "MainWindow", "flags","not-resizable"

    text 10,25 to 49,40, "URLlabel", "URL:", "MainWindow"

    text 10,68 to 52,88, "Submitlabel", "Submit", "MainWindow"

    text 10,105 to 59,125, "Resultslabel", "Result:", "MainWindow"

    draw rect  70,10 to 390,50, "MainWindow"

    Textedit 71,11 to 389,49, "URLField", 0,"MainWindow"

    Button 70, 60 to 390, 90, "tinyurlButton", "Submit this URL to tinyurl.com", "MainWindow"

    View 70, 100 to 390, 130, "ShortURLView", "MainWindow"

    Button 70, 140 to 280, 170, "copyButton", "Copy to clipboard", "MainWindow"

    option set "copyButton", "enabled", 0 //don't need this until we have a short URL

    Button 290, 140 to 390, 170, "aboutButton", "About", "MainWindow"

    DisplayShortURL()

    ExamineClipboard()

end sub

sub UIOnOff(state)

    //state must be 1 or 0

    option set "tinyurlButton", "enabled", state 

    option set "copyButton", "enabled", state 

    option set "aboutButton", "enabled", state 

end sub

It comes out looking like this:

If there's already a URL in your clipboard when you launch the program, it will be detected and pasted in for you.

BeInput

Wed, 05 Aug 2015 22:30:22 +0300

Found this among a bunch of old downloads

# BeInput 1.0
# Tanausu Gomez Garcia (_-Caleb-_)
# tanausugomez@gmail.com

BeInput is like a terminal's read command but in graphic mode.
Util for Script Writers.

Yab for haiku is still unstable.
Sometimes the program crash on startup.

Usage: BeInput User Label (Max 33 char. (yet))

Code:
# BeInput 1.0 (C) 

# Tanausu Gomez Garcia (_-Caleb-_)

# tanausugomez@gmail.com

# Comando Peek para usar argumentos

while (peek("argument"))

perso$=peek$("argument")

perso1$=peek$("argument")

perso2$=peek$("argument")

perso3$=peek$("argument")

perso4$=peek$("argument")

perso5$=peek$("argument")

perso6$=peek$("argument")

perso7$=peek$("argument")

perso8$=peek$("argument")

perso9$=peek$("argument")

perso10$=peek$("argument")

wend

# La ventana del programa"

window open 300,300 to 580,380, "View", "BeInput"

view 0,10 to 550,450, "View1", "View"

draw text 20,10, perso$ +" " + perso1$ +" " + perso2$ +" " + perso3$ +" " + perso4$ +" " + perso5$ +" " + perso6$ +" " + perso7$ +" " + perso8$ +" " + perso9$ +" " + perso10$, "View1"

button 80,40 to 200,60, "oki", "Ok", "View1"

textcontrol 10,15 to 270,180, "Datos", "", "","View1"

inloop = true

while(inloop)

msg$=message$

switch msg$

 case "View:_QuitRequested|"

        window close "View"

        end

     break

     case "oki|"

    Datos$=textcontrol get$ "Datos"

    output$=system$("echo "+Datos$+"")

        print output$

            window close "View"

            end

     break

end switch

wend

end